fec8d78f5346908e5fffa14521f091fe8b399bfc
[libav.git] / libavcodec / bfin / vp3_idct_bfin.S
1 /*
2 * vp3_idct BlackFin
3 *
4 * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com>
5 *
6 * This file is part of Libav.
7 *
8 * Libav is free software; you can redistribute it and/or
9 * modify it under the terms of the GNU Lesser General Public
10 * License as published by the Free Software Foundation; either
11 * version 2.1 of the License, or (at your option) any later version.
12 *
13 * Libav is distributed in the hope that it will be useful,
14 * but WITHOUT ANY WARRANTY; without even the implied warranty of
15 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
16 * Lesser General Public License for more details.
17 *
18 * You should have received a copy of the GNU Lesser General Public
19 * License along with Libav; if not, write to the Free Software
20 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 */
22 /*
23 This blackfin DSP code implements an 8x8 inverse type II DCT.
24
25 Prototype : void ff_bfin_vp3_idct(int16_t *in)
26
27 Registers Used : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0.
28
29 */
30
31 #include "config.h"
32 #include "config_bfin.h"
33
34 #if defined(__FDPIC__) && CONFIG_SRAM
35 .section .l1.data.B,"aw",@progbits
36 #else
37 .data
38 #endif
39
40 .align 4;
41 coefs:
42 .short 0x5a82; // C4
43 .short 0x5a82; // C4
44 .short 0x30FC; //cos(3pi/8) C6
45 .short 0x7642; //cos(pi/8) C2
46 .short 0x18F9; //cos(7pi/16)
47 .short 0x7D8A; //cos(pi/16)
48 .short 0x471D; //cos(5pi/16)
49 .short 0x6A6E; //cos(3pi/16)
50 .short 0x18F9; //cos(7pi/16)
51 .short 0x7D8A; //cos(pi/16)
52
53 #if defined(__FDPIC__) && CONFIG_SRAM
54 .section .l1.data.A,"aw",@progbits
55 #endif
56
57 vtmp: .space 256
58
59 #define TMP0 FP-8
60 #define TMP1 FP-12
61 #define TMP2 FP-16
62
63
64 .text
65 DEFUN(vp3_idct,mL1,
66 (int16_t *block)):
67
68 /********************** Function Prologue *********************************/
69 link 16;
70 [--SP] = (R7:4, P5:3); // Push the registers onto the stack.
71 B0 = R0; // Pointer to Input matrix
72 RELOC(R1, P3, coefs); // Pointer to Coefficients
73 RELOC(R2, P3, vtmp); // Pointer to Temporary matrix
74 B3 = R1;
75 B2 = R2;
76 L3 = 20; // L3 is used for making the coefficient array
77 // circular.
78 // MUST BE RESTORED TO ZERO at function exit.
79 M1 = 16 (X); // All these registers are initialized for
80 M3 = 8(X); // modifying address offsets.
81
82 I0 = B0; // I0 points to Input Element (0, 0).
83 I2 = B0; // I2 points to Input Element (0, 0).
84 I2 += M3 || R0.H = W[I0];
85 // Element 0 is read into R0.H
86 I1 = I2; // I1 points to input Element (0, 6).
87 I1 += 4 || R0.L = W[I2++];
88 // I2 points to input Element (0, 4).
89 // Element 4 is read into R0.L.
90 P2 = 8 (X);
91 P3 = 32 (X);
92 P4 = -32 (X);
93 P5 = 98 (X);
94 R7 = 0x8000(Z);
95 I3 = B3; // I3 points to Coefficients
96 P0 = B2; // P0 points to array Element (0, 0) of temp
97 P1 = B2;
98 R7 = [I3++] || [TMP2]=R7; // Coefficient C4 is read into R7.H and R7.L.
99 MNOP;
100 NOP;
101
102 /*
103 * A1 = Y0 * cos(pi/4)
104 * A0 = Y0 * cos(pi/4)
105 * A1 = A1 + Y4 * cos(pi/4)
106 * A0 = A0 - Y4 * cos(pi/4)
107 * load:
108 * R1=(Y2,Y6)
109 * R7=(C2,C6)
110 * res:
111 * R3=Y0, R2=Y4
112 */
113 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || I0+= 4 || R1.L=W[I1++];
114 R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
115
116 LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts
117
118 P2 = 112 (X);
119 P1 = P1 + P2; // P1 points to element (7, 0) of temp buffer.
120 P2 = -94(X);
121
122 .0:
123 /*
124 * A1 = Y2 * cos(3pi/8)
125 * A0 = Y2 * cos(pi/8)
126 * A1 = A1 - Y6 * cos(pi/8)
127 * A0 = A0 + Y6 * cos(3pi/8)
128 * R5 = (Y1,Y7)
129 * R7 = (C1,C7)
130 * res:
131 * R1=Y2, R0=Y6
132 */
133 A1=R7.L*R1.H, A0=R7.H*R1.H (IS) || I0+=4 || R5.H=W[I0];
134 R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS) || R5.L=W[I1--] || R7=[I3++];
135 /*
136 * Y0 = Y0 + Y6.
137 * Y4 = Y4 + Y2.
138 * Y2 = Y4 - Y2.
139 * Y6 = Y0 - Y6.
140 * R3 is saved
141 * R6.l=Y3
142 * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
143 */
144 R3=R3+R0, R0=R3-R0;
145 R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
146 /*
147 * Compute the odd portion (1,3,5,7) even is done.
148 *
149 * Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
150 * Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
151 * Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
152 * Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
153 */
154 // R5=(Y1,Y7) R6=(Y5,Y3) // R7=(C1,C7)
155 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || [TMP1]=R2 || R6.H=W[I2--];
156 A1-=R7.H*R5.L, A0+=R7.L*R5.L (IS) || I0-=4 || R7=[I3++];
157 A1+=R7.H*R6.H, A0+=R7.L*R6.H (IS) || I0+=M1; // R7=(C3,C5)
158 R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
159 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || R4=[TMP0];
160 A1+=R7.H*R5.L, A0-=R7.L*R5.L (IS) || I1+=M1 || R7=[I3++]; // R7=(C1,C7)
161 A1+=R7.L*R6.H, A0-=R7.H*R6.H (IS);
162 R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
163 // R3=Y1, R2=Y7, R7=Y5, R6=Y3
164
165 /* Transpose write column. */
166 R5.H=R4+R2 (RND12); // Y0=Y0+Y7
167 R5.L=R4-R2 (RND12) || R4 = [TMP1]; // Y7=Y7-Y0
168 R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H; // Y2=Y2+Y5 st Y0
169 R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++]; // Y5=Y2-Y5 st Y7
170 R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
171 R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
172 R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
173 R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
174
175 /* pipeline loop start, + drain Y3, Y4 */
176 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || W[P0++P2]= R3.H || R1.H = W[I0--];
177 .1: R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
178
179
180
181 I0 = B2; // I0 points to Input Element (0, 0)
182 I2 = B2; // I2 points to Input Element (0, 0)
183 I2 += M3 || R0.H = W[I0];
184 // Y0 is read in R0.H
185 I1 = I2; // I1 points to input Element (0, 6)
186 I1 += 4 || R0.L = W[I2++];
187 // I2 points to input Element (0, 4)
188 // Y4 is read in R0.L
189 P2 = 8 (X);
190 I3 = B3; // I3 points to Coefficients
191 P0 = B0; // P0 points to array Element (0, 0) for writing
192 // output
193 P1 = B0;
194 R7 = [I3++]; // R7.H = C4 and R7.L = C4
195 NOP;
196
197 /*
198 * A1 = Y0 * cos(pi/4)
199 * A0 = Y0 * cos(pi/4)
200 * A1 = A1 + Y4 * cos(pi/4)
201 * A0 = A0 - Y4 * cos(pi/4)
202 * load:
203 * R1=(Y2,Y6)
204 * R7=(C2,C6)
205 * res:
206 * R3=Y0, R2=Y4
207 */
208 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || I0+=4 || R1.L=W[I1++];
209 R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
210
211 LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts
212 P2 = 112 (X);
213 P1 = P1 + P2;
214 P2 = -94(X);
215
216 .2:
217 /*
218 * A1 = Y2 * cos(3pi/8)
219 * A0 = Y2 * cos(pi/8)
220 * A1 = A1 - Y6 * cos(pi/8)
221 * A0 = A0 + Y6 * cos(3pi/8)
222 * R5 = (Y1,Y7)
223 * R7 = (C1,C7)
224 * res:
225 * R1=Y2, R0=Y6
226 */
227 A1=R7.L*R1.H, A0=R7.H*R1.H (IS) || I0+=4 || R5.H=W[I0];
228 R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS) || R5.L=W[I1--] || R7=[I3++];
229 /*
230 * Y0 = Y0 + Y6.
231 * Y4 = Y4 + Y2.
232 * Y2 = Y4 - Y2.
233 * Y6 = Y0 - Y6.
234 * R3 is saved
235 * R6.l=Y3
236 * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
237 */
238 R3=R3+R0, R0=R3-R0;
239 R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
240 /*
241 * Compute the odd portion (1,3,5,7) even is done.
242 *
243 * Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
244 * Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
245 * Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
246 * Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
247 */
248 // R5=(Y1,Y7) R6=(Y5,Y3) // R7=(C1,C7)
249 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || [TMP1]=R2 || R6.H=W[I2--];
250 A1-=R7.H*R5.L, A0+=R7.L*R5.L (IS) || I0-=4 || R7=[I3++];
251 A1+=R7.H*R6.H, A0+=R7.L*R6.H (IS) || I0+=M1; // R7=(C3,C5)
252 R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
253 A1 =R7.L*R5.H, A0 =R7.H*R5.H (IS) || R4=[TMP0];
254 A1+=R7.H*R5.L, A0-=R7.L*R5.L (IS) || I1+=M1 || R7=[I3++]; // R7=(C1,C7)
255 A1+=R7.L*R6.H, A0-=R7.H*R6.H (IS);
256 R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
257 // R3=Y1, R2=Y7, R7=Y5, R6=Y3
258
259 /* Transpose write column. */
260 R5.H=R4+R2 (RND20); // Y0=Y0+Y7
261 R5.L=R4-R2 (RND20) || R4 = [TMP1]; // Y7=Y7-Y0
262 R5=R5>>>2(v);
263 R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H; // Y2=Y2+Y5 st Y0
264 R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++]; // Y5=Y2-Y5 st Y7
265 R2=R2>>>2(v);
266 R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
267 R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
268 R5=R5>>>2(v);
269 R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
270 R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
271 R3=R3>>>2(v);
272 /* pipeline loop start, + drain Y3, Y4 */
273 A1=R7.H*R0.H, A0=R7.H*R0.H (IS) || W[P0++P2]= R3.H || R1.H = W[I0--];
274 .3: R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
275
276 L3 = 0;
277 (R7:4,P5:3)=[SP++];
278 unlink;
279 RTS;
280 DEFUN_END(vp3_idct)